[BuC-ShoTz]

Originally Posted by DANNY G BuC-ShoTz could i please get a copy of that decrypter that you have created?

its just a batch file, make new txt file and paste this in it, name the text file .bat &
it needs to go inside scetool folder, and just drag and drop the self file on top of bat file.
the elf will be dump to the same folder as the input self

Echo OFF
COLOR 0F
MODE CON: COLS=67 LINES=35
TITLE Call of Duty PS3 Self Decrypter by BuC-ShoTz
set INFILE=%~1
set INFILEDIR=%~dp1
set COPYFILE=%~dp0%~nx1
set FILENAME=%~nx1
set FILENAMENOEXT=%~n1

call :ColorText 0c "Call of Duty PS3 Self Decrypter by BuC-ShoTz" end

:menuLOOP
echo.
echo.
call :ColorText 0c "= Menu ==========================================================" end
echo.
for /f "tokens=1,2,* delims=_ " %%A in ('"findstr /b /c:":klic_" "%~f0""') do echo.  %%B  %%C
echo.
call :ColorText 0c "=================================================================" end
set choice=
echo.&set /p choice=Choose the game you are trying to DECRYPT or hit ENTER to quit: ||GOTO:EOF

echo.&call:klic_%choice%
GOTO:menuLOOP

:klic_1   Call of Duty: Modern Warfare
call :ColorText 0c "Modern Warfare" end
echo.
set KLICENSE=496E66696E697479576172644B657900
GOTO:decrypt

:klic_2   Call of Duty: World at War
call :ColorText 0c "World at War" end
echo.
set KLICENSE=C8E0234D149E4549BC1B086FEFD7282A
GOTO:decrypt

:klic_3   Call of Duty: Modern Warfare 2
call :ColorText 0c "Modern Warfare 2" end
echo.
set KLICENSE=496E66696E697479576172644B657900
GOTO:decrypt

:klic_4   Call of Duty: Black Ops
call :ColorText 0c "Black Ops" end
echo.
set KLICENSE=AF0A8F0A8909F09234091AFADF909AF0
GOTO:decrypt

:klic_5   Call of Duty: Modern Warfare 3
call :ColorText 0c "Modern Warfare 3" end
echo.
set KLICENSE=496E66696E697479576172644B657900
GOTO:decrypt

:klic_6   Call of Duty: Black Ops 2
call :ColorText 0c "Black Ops 2" end
echo.
set KLICENSE=8C10AC1473DF38ADD7A4F2EE8C838DAB
GOTO:decrypt

:decrypt
COPY "%INFILE%" "%COPYFILE%"
echo.
pushd "%~dp0"
if "%FILENAME%" neq "EBOOT.BIN" (
	for %%i in ('%FILENAME%') do scetool.exe -v -l %KLICENSE% -d "%FILENAME%" "%FILENAMENOEXT%.elf"
	echo.
	COPY "%FILENAMENOEXT%.elf" "%INFILEDIR%%FILENAMENOEXT%.elf"
	echo.
	DEL "%FILENAMENOEXT%.elf"
	DEL "%FILENAME%"
	echo.
	call :ColorText 0c "=================================================================" end
	pause
	exit
)
if "%FILENAME%" equ "EBOOT.BIN" (
	for %%i in ('%FILENAME%') do scetool.exe -v -d "%FILENAME%" "%FILENAMENOEXT%.ELF"
	echo.
	COPY "%FILENAMENOEXT%.ELF" "%INFILEDIR%%FILENAMENOEXT%.ELF"
	echo.
	DEL "%FILENAMENOEXT%.ELF"
	DEL "%FILENAME%"
	echo.
	call :ColorText 0c "=================================================================" end
	pause
	exit
)

:ColorText %1 = Color %2 = Text
set /p ".=." > "%~2" <nul 
findstr /v /a:%1 /R "^$" "%~2" nul 2>nul
set /p ".=" <nul
if "%3" == "end" set /p ".=  " <nul
del "%~2" >nul 2>nul
exit /b